|
.NET平臺下WEB應用程序的部署(安裝數據庫和自動配置)
李洪根
在.NET平臺下，部署 Web 解決方案是比較方便的。我們可以利用Visual Studio.NET 2003添加一個WEB安裝項目，在部署的“文件系統編輯器”中添加項目的主輸出和內容文件，非常簡易地完成安裝程序的制作。
但是，這樣制作的安裝程序，只是將Web頁和ASP.NET程序編譯的DLL文件安裝到目標機器的IIS目錄，對于一般的應用程序是可以的（比如用Access數據庫，可以一起打包到安裝程序中）；如果數據庫是SQL SERVER，需要在部署的時候一并安裝數據庫，安裝程序的制作就會復雜一些，需要我們自定義安裝程序類。在安裝程序類中執行SQL腳本并將連接字符串寫入Web.config。
l 安裝數據庫
微軟MSDN上介紹過在部署應用程序的時候建立數據庫。如：
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/vsintro7/html/vxwlkWalkthroughUsingCustomActionToCreateDatabaseDuringInstallation.asp
這種方法是創建一個安裝程序類，在安裝程序類中調用ADO.NET執行SQL 語句（SQL語句放在一個文本文件中）來創建數據庫。
但是，這種方法有一個問題，如果用SQL Server2000生成了所有建表、視圖、存儲過程的一個腳本文件，用ADO.NET來執行這個腳本文件，就會因為腳本中有許多“GO”語句而出現錯誤。當然，我們可以把“GO”替換成換行符，利用ADO.NET一條條執行SQL 語句。很顯然，這樣的效率比較低。
最好的辦法是調用osql執行腳本。（或者創建一個數據庫項目的cmd文件，而cmd文件建立數據庫的時候也是調用的osql）。
首先，我們新建一個ASP.NET Web應用程序，http://localhost/VbNetTest，并打開VbNetTest 項目
創建部署項目
1. 在“文件”菜單上指向“添加項目”，然后選擇“新建項目”。
2. 在“添加新項目”對話框中，選擇“項目類型”窗格中的“安裝和部署項目”，然后選擇“模板”窗格中的“Web 安裝項目”。在“名稱”框中鍵入 Test Installer。
3. 單擊“確定”關閉對話框。
4. 項目被添加到解決方案資源管理器中，并且文件系統編輯器打開。
5. 在“屬性”窗口中，選擇 ProductName 屬性，并鍵入 GCRM。
將 VbNetTest項目的輸出添加到部署項目中
1. 在“文件系統編輯器”中，選擇“Web 應用程序”文件夾。在“操作”菜單上，指向“添加”，然后選擇“項目輸出”。
2. 在“添加項目輸出組”對話框中，選擇“項目”下拉列表中的“VbNetTest”。
3. 單擊“確定”關閉對話框。
4. 從列表中選擇“主輸出”和“內容文件”組，然后單擊“確定”。
創建安裝程序類
1. 在“文件”菜單上指向“新建”，然后選擇“項目”。
2. 在“新建項目”對話框中，選擇“項目類型”窗格中的“Visual Basic 項目”，然后選擇“模板”窗格中的“類庫”。在“名稱”框中鍵入 DBCustomAction。
3. 單擊“打開”關閉對話框。
4. 從“項目”菜單中選擇“添加新項”。
5. 在“添加新項”對話框中選擇“安裝程序類”。在“名稱”框中鍵入 DBCustomAction。
6. 單擊“確定”關閉對話框。
創建自定義安裝對話框
1. 在解決方案資源管理器中選擇“Test Installer”項目。在“視圖”菜單上指向“編輯器”，然后選擇“用戶界面”。
2. 在用戶界面編輯器中，選擇“安裝”下的“啟動”節點。在“操作”菜單上，選擇“添加對話框”。
3. 在“添加對話框”對話框中，選擇“許可協議”對話框，然后單擊“確定”關閉對話框。
4. 在“添加對話框”對話框中，選擇“文本框 (A)”對話框，然后單擊“確定”關閉對話框。
5. 在“操作”菜單上，選擇“上移”。重復此步驟，直到“文本框 (A)”對話框位于“安裝文件夾”節點之上。
6. 在“屬性”窗口中，選擇 BannerText 屬性并鍵入：安裝數據庫.。
7. 選擇 BodyText 屬性并鍵入：安裝程序將在目標機器上安裝數據庫。
8. 選擇 Edit1Label 屬性并鍵入：數據庫名稱:。
9. 選擇 Edit1Property 屬性并鍵入 CUSTOMTEXTA1。
10. 選擇 Edit1Value 屬性并鍵入：GsCrm。
11. 選擇 Edit2Label 屬性并鍵入：服務器名:。
12. 選擇 Edit2Property 屬性并鍵入 CUSTOMTEXTA2。
13. 選擇 Edit2Value 屬性并鍵入：(local)。
14. 選擇 Edit3Label 屬性并鍵入：用戶名:。
15. 選擇 Edit3Value 屬性并鍵入：sa。
16. 選擇 Edit3Property 屬性并鍵入 CUSTOMTEXTA3。
17. 選擇 Edit4Label 屬性并鍵入：密碼:。
18. 選擇 Edit4Property 屬性并鍵入 CUSTOMTEXTA4。
19. 選擇 Edit2Visible、Edit3Visible 和 Edit4Visible 屬性，并將它們設置為 False。
創建自定義操作
1. 在解決方案資源管理器中選擇“Test Installer”項目。在“視圖”菜單上指向“編輯器”，然后選擇“自定義操作”。
2. 在自定義操作編輯器中選擇“安裝”節點。在“操作”菜單上，選擇“添加自定義操作”。
3. 在“選擇項目中的項”對話框中，雙擊“應用程序文件夾”。
4. 選擇“主輸出來自 DBCustomAction（活動）”項，然后單擊“確定”關閉對話框。
5. 在“屬性”窗口中，選擇 CustomActionData 屬性并鍵入 /dbname=[CUSTOMTEXTA1] /server=[CUSTOMTEXTA2] /user=[CUSTOMTEXTA3] /pwd=[CUSTOMTEXTA4] /targetdir="[TARGETDIR]\"。
附/targetdir="[TARGETDIR]\"是安裝后的目標路徑，為了在DBCustomAction類中獲得安裝后的路徑，我們設置此參數。
另外，安裝后的路徑也可以通過Reflection得到：
Dim Asm As System.Reflection.Assembly = _
System.Reflection.Assembly.GetExecutingAssembly
MsgBox("Asm.Location")
添加文件
1. 將SQL Server生成的腳本文件DB.sql添加到“Test Installer”項目
2. 將安裝文件LisenceFile.rtf添加到“Test Installer”項目
3. 在用戶界面編輯器中，選擇許可協議，設置LisenceFile屬性為LisenceFile.rtf文件
工程中的文件 :
將代碼添加到安裝程序類中，DBCustomAction.vb類
Imports System.ComponentModel
Imports System.Configuration.Install
Imports System.IO
Imports System.Reflection
<RunInstaller(True)> Public Class DBCustomAction
Inherits System.Configuration.Install.Installer
#Region "組件設計器生成的代碼 "
Public Sub New()
MyBase.New()
'該調用是組件設計器所必需的
InitializeComponent()
'在 InitializeComponent() 調用之后添加任何初始化
End Sub
' Installer 重寫 dispose 以清理組件列表。
Protected Overloads Overrides Sub Dispose(ByVal disposing As Boolean)
If disposing Then
If Not (components Is Nothing) Then
components.Dispose()
End If
End If
MyBase.Dispose(disposing)
End Sub
Private components As System.ComponentModel.IContainer
<System.Diagnostics.DebuggerStepThrough()> Private Sub InitializeComponent()
End Sub
#End Region
'執行SQL 語句
Private Sub ExecuteSql(ByVal conn As String, ByVal DatabaseName As String, ByVal Sql As String)
Dim mySqlConnection As New SqlClient.SqlConnection(conn)
Dim Command As New SqlClient.SqlCommand(Sql, mySqlConnection)
Command.Connection.Open()
Command.Connection.ChangeDatabase(DatabaseName)
Try
Command.ExecuteNonQuery()
Finally
'Close Connection
Command.Connection.Close()
End Try
End Sub
Public Overrides Sub Install(ByVal stateSaver As System.Collections.IDictionary)
MyBase.Install(stateSaver)
' ------------------------建立數據庫-------------------------------------------------
Try
Dim connStr As String = String.Format("data source={0};user id={1};password={2};persist security info=false;packet size=4096", Me.Context.Parameters.Item("server"), Me.Context.Parameters.Item("user"), Me.Context.Parameters.Item("pwd"))
'根據輸入的數據庫名稱建立數據庫
ExecuteSql(connStr, "master", "CREATE DATABASE " + Me.Context.Parameters.Item("dbname"))
'調用osql執行腳本
Dim sqlProcess As New System.Diagnostics.Process
sqlProcess.StartInfo.FileName = "osql.exe "
sqlProcess.StartInfo.Arguments = String.Format(" -U {0} -P {1} -d {2} -i {3}db.sql", Me.Context.Parameters.Item("user"), Me.Context.Parameters.Item("pwd"), Me.Context.Parameters.Item("dbname"), Me.Context.Parameters.Item("targetdir"))
sqlProcess.StartInfo.WindowStyle = ProcessWindowStyle.Hidden
sqlProcess.Start()
sqlProcess.WaitForExit() '等待執行
sqlProcess.Close()
'刪除腳本文件
Dim sqlFileInfo As New System.IO.FileInfo(String.Format("{0}db.sql", Me.Context.Parameters.Item("targetdir")))
If sqlFileInfo.Exists Then
sqlFileInfo.Delete()
End If
Catch ex As Exception
Throw ex
End Try
' ---------------------將連接字符串寫入Web.config-----------------------------------
Try
Dim FileInfo As System.IO.FileInfo = New System.IO.FileInfo(Me.Context.Parameters.Item("targetdir") & "\web.config")
If Not FileInfo.Exists Then
Throw New InstallException("沒有找到配置文件")
End If
'實例化XML文檔
Dim XmlDocument As New System.Xml.XmlDocument
XmlDocument.Load(FileInfo.FullName)
'查找到appSettings中的節點
Dim Node As System.Xml.XmlNode
Dim FoundIt As Boolean = False
For Each Node In XmlDocument.Item("configuration").Item("appSettings")
If Node.Name = "add" Then
If Node.Attributes.GetNamedItem("key").Value = "connString" Then
'寫入連接字符串
Node.Attributes.GetNamedItem("value").Value = String.Format("Persist Security Info=False;Data Source={0};Initial Catalog={1};User ID={2};Password={3};Packet Size=4096;Pooling=true;Max Pool Size=100;Min Pool Size=1", _
Me.Context.Parameters.Item("server"), Me.Context.Parameters.Item("dbname"), Me.Context.Parameters.Item("user"), Me.Context.Parameters.Item("pwd"))
FoundIt = True
End If
End If
Next Node
If Not FoundIt Then
Throw New InstallException("web.Config 文件沒有包含connString連接字符串設置")
End If
XmlDocument.Save(FileInfo.FullName)
Catch ex As Exception
Throw ex
End Try
End Sub
End Class
最后編譯生成！
安裝界面：
聲明：本文版權與解釋權歸李洪根所有，如需轉載，請保留完整的內容及此聲明。
QQ: 21177563 MSN: lihonggen@hotmail.com
專欄：http://www.csdn.net/develop/author/netauthor/lihonggen0/
|
